home *** CD-ROM | disk | FTP | other *** search
/ Turnbull China Bikeride / Turnbull China Bikeride - Disc 2.iso / STUTTGART / TEX-UTIL / DVIVIEW / TEXFONTS5 / !TeXFonts / NotRISCOS / bigop / mf
Text File  |  1988-02-26  |  17KB  |  388 lines
  1. % This is BIGOP.MF in text format, as of Mar 31, 1986.
  2. % This file contains pairs of large operators for math extension fonts.
  3.  
  4. % Each operator has a `{\tt\char`\\textstyle}' form, for math in text,
  5. % and a `{\tt\char`\\displaystyle}' form, for displayed formulas.
  6.  
  7. % Character codes \0106--\0141 are generated.
  8.  
  9. charlist oct"106": oct"107";  % square union signs
  10. charlist oct"110": oct"111";  % contour integral signs
  11. charlist oct"112": oct"113";  % circle-dot operators
  12. charlist oct"114": oct"115";  % circle-plus operators
  13. charlist oct"116": oct"117";  % circle-times operators
  14. charlist oct"120": oct"130";  % summation signs
  15. charlist oct"121": oct"131";  % product signs
  16. charlist oct"122": oct"132";  % integral signs
  17. charlist oct"123": oct"133";  % union signs
  18. charlist oct"124": oct"134";  % intersection signs
  19. charlist oct"125": oct"135";  % multiset union signs
  20. charlist oct"126": oct"136";  % lattice infimum signs
  21. charlist oct"127": oct"137";  % lattice supremum signs
  22. charlist oct"140": oct"141";  % coproduct signs
  23.  
  24. cmchar "\textstyle square set union sign";
  25. beginchar(oct"106",15u#,0,10/6dh#);
  26. adjust_fit(0,0); pickup pencircle scaled stem;
  27. lft x1=hround u; x2=x1; x4=x5=w-x1;
  28. top y1=eps; bot y2=-d; y4=y2; y5=y1;
  29. draw z1---z2---z4---z5;  % stems and bar
  30. labels(1,2,4,5); endchar;
  31.  
  32. cmchar "\displaystyle square set union sign";
  33. beginchar(oct"107",20u#,0,14/6dh#); padded 1/6dh#;
  34. adjust_fit(0,0); pickup pencircle scaled curve;
  35. lft x1=hround u; x2=x1; x4=x5=w-x1;
  36. top y1=eps; bot y2=-d; y4=y2; y5=y1;
  37. draw z1---z2---z4---z5;  % stems and bar
  38. labels(1,2,4,5); endchar;
  39.  
  40. cmchar "\textstyle circle-dot operator";
  41. beginchar(oct"112",20u#,0,10/6dh#);
  42. adjust_fit(0,0); pickup pencircle scaled stem;
  43. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  44. circle_points; draw_circle;  % circle
  45. fill fullcircle scaled(bold+4dw+eps) shifted(.5[z4,z8]);  % dot
  46. labels(1,2,3,4,5,6,7,8); endchar;
  47.  
  48. cmchar "\displaystyle circle-dot operator";
  49. beginchar(oct"113",27.2u#,0,14/6dh#); padded 1/6dh#;
  50. adjust_fit(0,0); pickup pencircle scaled curve;
  51. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  52. circle_points; draw_circle;  % circle
  53. fill fullcircle scaled(bold+6dw+eps) shifted(.5[z4,z8]);  % dot
  54. labels(1,2,3,4,5,6,7,8); endchar;
  55.  
  56. cmchar "\textstyle circle-plus operator";
  57. beginchar(oct"114",20u#,0,10/6dh#);
  58. adjust_fit(0,0); pickup pencircle scaled stem;
  59. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  60. circle_points; draw_circle;  % circle
  61. draw z2--z6; draw z4--z8;  % plus
  62. labels(1,2,3,4,5,6,7,8); endchar;
  63.  
  64. cmchar "\displaystyle circle-plus operator";
  65. beginchar(oct"115",27.2u#,0,14/6dh#); padded 1/6dh#;
  66. adjust_fit(0,0); pickup pencircle scaled curve;
  67. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  68. circle_points; draw_circle;  % circle
  69. draw z2--z6; draw z4--z8;  % plus
  70. labels(1,2,3,4,5,6,7,8); endchar;
  71.  
  72. cmchar "\textstyle circle-times operator";
  73. beginchar(oct"116",20u#,0,10/6dh#);
  74. adjust_fit(0,0); pickup pencircle scaled stem;
  75. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  76. circle_points; draw_circle;  % circle
  77. draw z1--z5; draw z3--z7;  % times
  78. labels(1,2,3,4,5,6,7,8); endchar;
  79.  
  80. cmchar "\displaystyle circle-times operator";
  81. beginchar(oct"117",27.2u#,0,14/6dh#); padded 1/6dh#;
  82. adjust_fit(0,0); pickup pencircle scaled curve;
  83. lft x6=hround u; x2=w-x6; top y8=0; bot y4=-d;
  84. circle_points; draw_circle;  % circle
  85. draw z1--z5; draw z3--z7;  % times
  86. labels(1,2,3,4,5,6,7,8); endchar;
  87.  
  88. cmchar "\textstyle summation sign";
  89. beginchar(oct"120",19u#,0,10/6dh#);
  90. adjust_fit(0,0); pickup tiny.nib;
  91. numeric top_arm_thickness, bot_arm_thickness;
  92. top_arm_thickness=Vround rule_thickness;
  93. bot_arm_thickness=Vround .9(.5[rule_thickness,curve]);
  94. lft x1l=hround u; x1l=x2l=x4l; x3l-x1l=4/11(w-2u);
  95. top y1=0; bot y2=-top_arm_thickness-eps; bot y4=-d; y3=-.5d;
  96. numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
  97. penpos1(alpha1*(curve-tiny),0); penpos2(alpha1*(curve-tiny),0);
  98. penpos3(alpha1*(curve-tiny),0);
  99. alpha2=diag_ratio(1,rule_thickness-tiny,y3-y4,x3r-x4l);
  100. penpos4(alpha2*(rule_thickness-tiny),0);
  101. z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
  102. filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle;  % diagonals
  103. pickup crisp.nib; pos5(top_arm_thickness,90); pos6(hair,0);
  104. top y5r=0; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-beak)-eps;
  105. arm(5,6,a,.45,17/11u);  % upper arm and beak
  106. pos7(bot_arm_thickness,-90); pos8(hair,0);
  107. bot y7r=-d; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+beak)+eps;
  108. arm(7,8,b,.45,17/11u);  % lower arm and beak
  109. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  110.  
  111. cmchar "\displaystyle summation sign";
  112. beginchar(oct"130",26u#,0,14/6dh#); padded 1/6dh#;
  113. adjust_fit(0,0); pickup tiny.nib;
  114. numeric top_arm_thickness, bot_arm_thickness, thick_stem, thin_stem;
  115. thick_stem=bold+4dw; thin_stem=rule_thickness+dw;
  116. top_arm_thickness=Vround .9thin_stem;
  117. bot_arm_thickness=Vround .9(.5[thin_stem,thick_stem]);
  118. lft x1l=hround u; x1l=x2l=x4l; x3l-x1l=4/11(w-2u);
  119. top y1=0; bot y2=-top_arm_thickness-eps; bot y4=-d; y3=-.5d;
  120. numeric alpha[]; alpha1=((x3l-x1l)++(y2-y3))/(y2-y3);
  121. penpos1(alpha1*(thick_stem-tiny),0); penpos2(alpha1*(thick_stem-tiny),0);
  122. penpos3(alpha1*(thick_stem-tiny),0);
  123. alpha2=diag_ratio(1,thin_stem-tiny,y3-y4,x3r-x4l);
  124. penpos4(alpha2*(thin_stem-tiny),0);
  125. z0=whatever[z2l,z3l]=z4l+whatever*(z3r-z4r);
  126. filldraw z1l--z2l--z0--z4l--z4r--z3r--z2r--z1r--cycle;  % diagonals
  127. pickup crisp.nib; pos5(top_arm_thickness,90); pos6(hair,0);
  128. top y5r=0; x5=x1; rt x6r=hround(w-u); y6=good.y(y5l-1.2beak)-eps;
  129. arm(5,6,a,.45,24/11u);  % upper arm and beak
  130. pos7(bot_arm_thickness,-90); pos8(hair,0);
  131. bot y7r=-d; z7l=whatever[z4,z3]; x7r:=x4; x8=x6; y8=good.y(y7l+1.2beak)+eps;
  132. arm(7,8,b,.45,24/11u);  % lower arm and beak
  133. penlabels(0,1,2,3,4,5,6,7,8); endchar;
  134.  
  135. cmchar "\textstyle product sign";
  136. beginchar(oct"121",17u#,0,10/6dh#);
  137. adjust_fit(0,0); pickup crisp.nib;
  138. numeric heavy_stem,light_stem;
  139. heavy_stem=hround(bold+dw); light_stem=rule_thickness;
  140. pos1(heavy_stem,0);pos2(heavy_stem,0); pos1'(heavy_stem,0);pos2'(heavy_stem,0);
  141. pos11(light_stem,90); pos12(light_stem,90); pos22(light_stem,90);
  142. lft x11=hround u; x1l-x11=x2l-x12=x22-x2r=hround cap_jut;
  143. x1=x1'=x2=x2';
  144. top y1=0; bot y2=-d; y11r=y1; y12l=y22l=y2;
  145. y11l-y1'=y2'-y12r=1.2bracket;
  146. filldraw z1r--z11r--serif_arc(11l,1'l)--reverse serif_arc(12r,2'l)
  147.  --z12l--z22l--serif_arc(22r,2'r)--cycle;  % left stem and serifs
  148. pos3(heavy_stem,0);pos4(heavy_stem,0); pos3'(heavy_stem,0);pos4'(heavy_stem,0);
  149. pos13(light_stem,90); pos14(light_stem,90); pos24(light_stem,90);
  150. x3=x3'=x4=x4'=w-x1; x13=x14=w-x11; x24=w-x22;
  151. y3=y13r=y1; y3'=y1'; y4'=y2'; y4=y14l=y24l=y2;
  152. filldraw z3l--z13r--serif_arc(13l,3'r)--reverse serif_arc(14r,4'r)
  153.  --z14l--z24l--serif_arc(24r,4'l)--cycle;  % right stem and serifs
  154. filldraw stroke z11e--z13e; % bar
  155. penlabels(1,1',2,2',3,3',4,4',11,12,13,14,22,24); endchar;
  156.  
  157. cmchar "\displaystyle product sign";
  158. beginchar(oct"131",23u#,0,14/6dh#); padded 1/6dh#;
  159. adjust_fit(0,0); pickup crisp.nib;
  160. numeric heavy_stem,light_stem;
  161. heavy_stem=hround(bold+5dw); light_stem=Vround(rule_thickness+dw);
  162. pos1(heavy_stem,0);pos2(heavy_stem,0); pos1'(heavy_stem,0);pos2'(heavy_stem,0);
  163. pos11(light_stem,90); pos12(light_stem,90); pos22(light_stem,90);
  164. lft x11=hround u; x1l-x11=x2l-x12=x22-x2r=hround 1.6cap_jut;
  165. x1=x1'=x2=x2';
  166. top y1=0; bot y2=-d; y11r=y1; y12l=y22l=y2;
  167. y11l-y1'=y2'-y12r=1.8bracket;
  168. filldraw z1r--z11r--serif_arc(11l,1'l)--reverse serif_arc(12r,2'l)
  169.  --z12l--z22l--serif_arc(22r,2'r)--cycle;  % left stem and serifs
  170. pos3(heavy_stem,0);pos4(heavy_stem,0); pos3'(heavy_stem,0);pos4'(heavy_stem,0);
  171. pos13(light_stem,90); pos14(light_stem,90); pos24(light_stem,90);
  172. x3=x3'=x4=x4'=w-x1; x13=x14=w-x11; x24=w-x22;
  173. y3=y13r=y1; y3'=y1'; y4'=y2'; y4=y14l=y24l=y2;
  174. filldraw z3l--z13r--serif_arc(13l,3'r)--reverse serif_arc(14r,4'r)
  175.  --z14l--z24l--serif_arc(24r,4'l)--cycle;  % right stem and serifs
  176. filldraw stroke z11e--z13e; % bar
  177. penlabels(1,1',2,2',3,3',4,4',11,12,13,14,22,24); endchar;
  178.  
  179. cmchar "\textstyle coproduct sign";
  180. beginchar(oct"140",17u#,0,10/6dh#);
  181. adjust_fit(0,0); pickup crisp.nib;
  182. numeric heavy_stem,light_stem;
  183. heavy_stem=hround(bold+dw); light_stem=rule_thickness;
  184. pos1(heavy_stem,0);pos2(heavy_stem,0); pos1'(heavy_stem,0);pos2'(heavy_stem,0);
  185. pos11(light_stem,-90); pos12(light_stem,-90); pos22(light_stem,-90);
  186. lft x11=hround u; x1l-x11=x2l-x12=x22-x2r=hround cap_jut;
  187. x1=x1'=x2=x2';
  188. bot y1=-d; top y2=0; y11r=y1; y12l=y22l=y2;
  189. y1'-y11l=y12r-y2'=1.2bracket;
  190. filldraw z1r--z11r--serif_arc(11l,1'l)--reverse serif_arc(12r,2'l)
  191.  --z12l--z22l--serif_arc(22r,2'r)--cycle;  % left stem and serifs
  192. pos3(heavy_stem,0);pos4(heavy_stem,0); pos3'(heavy_stem,0);pos4'(heavy_stem,0);
  193. pos13(light_stem,-90); pos14(light_stem,-90); pos24(light_stem,-90);
  194. x3=x3'=x4=x4'=w-x1; x13=x14=w-x11; x24=w-x22;
  195. y3=y13r=y1; y3'=y1'; y4'=y2'; y4=y14l=y24l=y2;
  196. filldraw z3l--z13r--serif_arc(13l,3'r)--reverse serif_arc(14r,4'r)
  197.  --z14l--z24l--serif_arc(24r,4'l)--cycle;  % right stem and serifs
  198. filldraw stroke z11e--z13e; % bar
  199. penlabels(1,1',2,2',3,3',4,4',11,12,13,14,22,24); endchar;
  200.  
  201. cmchar "\displaystyle coproduct sign";
  202. beginchar(oct"141",23u#,0,14/6dh#); padded 1/6dh#;
  203. adjust_fit(0,0); pickup crisp.nib;
  204. numeric heavy_stem,light_stem;
  205. heavy_stem=hround(bold+5dw); light_stem=Vround(rule_thickness+dw);
  206. pos1(heavy_stem,0);pos2(heavy_stem,0); pos1'(heavy_stem,0);pos2'(heavy_stem,0);
  207. pos11(light_stem,-90); pos12(light_stem,-90); pos22(light_stem,-90);
  208. lft x11=hround u; x1l-x11=x2l-x12=x22-x2r=hround cap_jut;
  209. x1=x1'=x2=x2';
  210. bot y1=-d; top y2=0; y11r=y1; y12l=y22l=y2;
  211. y1'-y11l=y12r-y2'=1.8bracket;
  212. filldraw z1r--z11r--serif_arc(11l,1'l)--reverse serif_arc(12r,2'l)
  213.  --z12l--z22l--serif_arc(22r,2'r)--cycle;  % left stem and serifs
  214. pos3(heavy_stem,0);pos4(heavy_stem,0); pos3'(heavy_stem,0);pos4'(heavy_stem,0);
  215. pos13(light_stem,-90); pos14(light_stem,-90); pos24(light_stem,-90);
  216. x3=x3'=x4=x4'=w-x1; x13=x14=w-x11; x24=w-x22;
  217. y3=y13r=y1; y3'=y1'; y4'=y2'; y4=y14l=y24l=y2;
  218. filldraw z3l--z13r--serif_arc(13l,3'r)--reverse serif_arc(14r,4'r)
  219.  --z14l--z24l--serif_arc(24r,4'l)--cycle;  % right stem and serifs
  220. filldraw stroke z11e--z13e; % bar
  221. penlabels(1,1',2,2',3,3',4,4',11,12,13,14,22,24); endchar;
  222.  
  223. cmchar "\textstyle integral sign";
  224. beginchar(oct"122",12u#,0,100/54dh#);
  225. italcorr 3.5u#; % \TeX\ kerning between upper limit and lower limit
  226. adjust_fit(0,-ic#); pickup fine.nib;
  227. pos1(curve,0); pos2(hair,0); pos3(vair,90); pos4(stem,180);
  228. pos5(curve,180); pos5'(curve,0); z5'=z5; pos6(stem,0);
  229. pos7(vair,-90); pos8(hair,-180); pos9(curve,-180);
  230. rt x1r=hround(w-u); x9=w-x1; x7=w-x3=3u;
  231. x5=.5[x4,x6]; x4-x6=1.2u; lft x5r=hround(.5w-.5stem);
  232. top y3r=0; bot y7r=-d; y9-.5curve=vround(top y7l+.25curve);
  233. y3-y1=y9-y7; y5=.5[y3,y7]=.5[y4,y6]; y4-y6=.6(y3-y7);
  234. bulb(3,2,1); bulb(7,8,9);  % bulbs
  235. filldraw stroke z3e{left}...z4e{(z5e-z4e)xscaled 1.1}
  236.  ..tension atleast 1 and atleast .8..{z5-z4}z5e;  % upper stem
  237. filldraw stroke z5'e{z6-z5}..tension atleast.8 and atleast 1
  238.  ..{(z6e-z5'e)xscaled 1.1}z6e...{left}z7e;  % lower stem
  239. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  240.  
  241. cmchar "\displaystyle integral sign";
  242. beginchar(oct"132",18u#,0,200/54dh#);
  243. italcorr 8u#; % \TeX\ kerning between upper limit and lower limit
  244. adjust_fit(0,-ic#); pickup fine.nib;
  245. numeric bulb_size, max_size;
  246. bulb_size=hround(bold+dw); max_size=hround(bold+2dw);
  247. pos1(bulb_size,0); pos2(hair,0); pos3(vair,90); pos4(bold,180);
  248. pos5(max_size,180); pos5'(max_size,0); z5'=z5; pos6(bold,0);
  249. pos7(vair,-90); pos8(hair,-180); pos9(bulb_size,-180);
  250. rt x1r=hround(w-u); x9=w-x1; x7=w-x3=3u;
  251. x5=.5[x4,x6]; x4-x6=4.8u; lft x5r=hround(.5w-.5stem);
  252. top y3r=0; bot y7r=-d;
  253. y9-.5bulb_size=vround(top y7l+.25bulb_size); y3-y1=y9-y7;
  254. y5=.5[y3,y7]=.5[y4,y6]; y4-y6=.6(y3-y7);
  255. bulb(3,2,1); bulb(7,8,9);  % bulbs
  256. filldraw stroke z3e{left}...z4e{(z5e-z4e)xscaled 1.1}
  257.  ..tension atleast 1 and atleast .8..{z5-z4}z5e;  % upper stem
  258. filldraw stroke z5'e{z6-z5}..tension atleast.8 and atleast 1
  259.  ..{(z6e-z5'e)xscaled 1.1}z6e...{left}z7e;  % lower stem
  260. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  261.  
  262. cmchar "\textstyle contour integral sign";
  263. beginchar(oct"110",12u#,0,100/54dh#);
  264. italcorr 3.5u#; % \TeX\ kerning between upper limit and lower limit
  265. adjust_fit(0,-ic#); pickup fine.nib;
  266. pos1(curve,0); pos2(hair,0); pos3(vair,90); pos4(stem,180);
  267. pos5(curve,180); pos5'(curve,0); z5'=z5; pos6(stem,0);
  268. pos7(vair,-90); pos8(hair,-180); pos9(curve,-180);
  269. rt x1r=hround(w-u); x9=w-x1; x7=w-x3=3u;
  270. x5=.5[x4,x6]; x4-x6=1.2u; lft x5r=hround(.5w-.5stem);
  271. top y3r=0; bot y7r=-d; y9-.5curve=vround(top y7l+.25curve);
  272. y3-y1=y9-y7; y5=.5[y3,y7]=.5[y4,y6]; y4-y6=.6(y3-y7);
  273. bulb(3,2,1); bulb(7,8,9);  % bulbs
  274. filldraw stroke z3e{left}...z4e{(z5e-z4e)xscaled 1.1}
  275.  ..tension atleast 1 and atleast .8..{z5-z4}z5e;  % upper stem
  276. filldraw stroke z5'e{z6-z5}..tension atleast.8 and atleast 1
  277.  ..{(z6e-z5'e)xscaled 1.1}z6e...{left}z7e;  % lower stem
  278. pickup rule.nib; autorounded;
  279. draw fullcircle scaled .5w shifted z5;  % contour
  280. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  281.  
  282. cmchar "\displaystyle contour integral sign";
  283. beginchar(oct"111",18u#,0,200/54dh#);
  284. italcorr 8u#; % \TeX\ kerning between upper limit and lower limit
  285. adjust_fit(0,-ic#); pickup fine.nib;
  286. numeric bulb_size, max_size;
  287. bulb_size=hround(bold+dw); max_size=hround(bold+2dw);
  288. pos1(bulb_size,0); pos2(hair,0); pos3(vair,90); pos4(bold,180);
  289. pos5(max_size,180); pos5'(max_size,0); z5'=z5; pos6(bold,0);
  290. pos7(vair,-90); pos8(hair,-180); pos9(bulb_size,-180);
  291. rt x1r=hround(w-u); x9=w-x1; x7=w-x3=3u;
  292. x5=.5[x4,x6]; x4-x6=4.8u; lft x5r=hround(.5w-.5stem);
  293. top y3r=0; bot y7r=-d;
  294. y9-.5bulb_size=vround(top y7l+.25bulb_size); y3-y1=y9-y7;
  295. y5=.5[y3,y7]=.5[y4,y6]; y4-y6=.6(y3-y7);
  296. bulb(3,2,1); bulb(7,8,9);  % bulbs
  297. filldraw stroke z3e{left}...z4e{(z5e-z4e)xscaled 1.1}
  298.  ..tension atleast 1 and atleast .8..{z5-z4}z5e;  % upper stem
  299. filldraw stroke z5'e{z6-z5}..tension atleast.8 and atleast 1
  300.  ..{(z6e-z5'e)xscaled 1.1}z6e...{left}z7e;  % lower stem
  301. pickup rule.nib; autorounded;
  302. draw fullcircle scaled .5w shifted z5;  % contour
  303. penlabels(1,2,3,4,5,6,7,8,9); endchar;
  304.  
  305. cmchar "\textstyle set union sign";
  306. beginchar(oct"123",15u#,0,10/6dh#);
  307. adjust_fit(0,0); pickup pencircle scaled stem;
  308. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  309. top y1=eps; bot y3=-d; y2=y4=2/3[y1,y3]; y5=y1;
  310. draw z1---z2...z3...z4---z5;  % stems and cup
  311. labels(1,2,3,4,5); endchar;
  312.  
  313. cmchar "\displaystyle set union sign";
  314. beginchar(oct"133",20u#,0,14/6dh#); padded 1/6dh#;
  315. adjust_fit(0,0); pickup pencircle scaled curve;
  316. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  317. top y1=eps; bot y3=-d; y2=y4=2/3[y1,y3]; y5=y1;
  318. draw z1---z2...z3...z4---z5;  % stems and cup
  319. labels(1,2,3,4,5); endchar;
  320.  
  321. cmchar "\textstyle set intersection sign";
  322. beginchar(oct"124",15u#,0,10/6dh#);
  323. adjust_fit(0,0); pickup pencircle scaled stem;
  324. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  325. top y3=0; bot y1=-d-eps; y2=y4=2/3[y1,y3]; y5=y1;
  326. draw z1---z2...z3...z4---z5;  % stems and cap
  327. labels(1,2,3,4,5); endchar;
  328.  
  329. cmchar "\displaystyle set intersection sign";
  330. beginchar(oct"134",20u#,0,14/6dh#); padded 1/6dh#;
  331. adjust_fit(0,0); pickup pencircle scaled curve;
  332. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  333. top y3=0; bot y1=-d-eps; y2=y4=2/3[y1,y3]; y5=y1;
  334. draw z1---z2...z3...z4---z5;  % stems and cap
  335. labels(1,2,3,4,5); endchar;
  336.  
  337. cmchar "\textstyle multiset union sign";
  338. beginchar(oct"125",15u#,0,10/6dh#);
  339. adjust_fit(0,0); pickup pencircle scaled stem;
  340. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  341. top y1=eps; bot y3=-d; y2=y4=2/3[y1,y3]; y5=y1;
  342. draw z1---z2...z3...z4---z5;  % stems and cup
  343. y8=y9=.47[y1,y3]; x8=w-x9=x1+2stem+eps; x6=x7=x3;
  344. .5[y6,y7]=y8; y7-y6=x9-x8; draw z8--z9; draw z6--z7;  % enclosed `$+$'
  345. labels(1,2,3,4,5,6,7,8,9); endchar;
  346.  
  347. cmchar "\displaystyle multiset union sign";
  348. beginchar(oct"135",20u#,0,14/6dh#); padded 1/6dh#;
  349. adjust_fit(0,0); pickup pencircle scaled curve;
  350. lft x1=hround u; x2=x1; x3=w-x3; x4=x5=w-x1;
  351. top y1=eps; bot y3=-d; y2=y4=2/3[y1,y3]; y5=y1;
  352. draw z1---z2...z3...z4---z5;  % stems and cup
  353. y8=y9=.47[y1,y3]; x8=w-x9=x1+2curve+eps; x6=x7=x3;
  354. .5[y6,y7]=y8; y7-y6=x9-x8; draw z8--z9; draw z6--z7;  % enclosed `$+$'
  355. labels(1,2,3,4,5,6,7,8,9); endchar;
  356.  
  357. cmchar "\textstyle lattice infimum sign";
  358. beginchar(oct"126",15u#,0,10/6dh#);
  359. adjust_fit(0,0); pickup pencircle scaled stem;
  360. lft x1=hround u-eps; x3=w-x3; x5=w-x1;
  361. top y3=0; bot y1=-d-eps; y5=y1;
  362. draw z1--z3--z5;  % diagonals
  363. labels(1,3,5); endchar;
  364.  
  365. cmchar "\displaystyle lattice infimum sign";
  366. beginchar(oct"136",20u#,0,14/6dh#); padded 1/6dh#;
  367. adjust_fit(0,0); pickup pencircle scaled curve;
  368. lft x1=hround u-eps; x3=w-x3; x5=w-x1;
  369. top y3=0; bot y1=-d-eps; y5=y1;
  370. draw z1--z3--z5;  % diagonals
  371. labels(1,3,5); endchar;
  372.  
  373. cmchar "\textstyle lattice supremum sign";
  374. beginchar(oct"127",15u#,0,10/6dh#);
  375. adjust_fit(0,0); pickup pencircle scaled stem;
  376. lft x1=hround u-eps; x3=w-x3; x5=w-x1;
  377. top y1=eps; bot y3=-d; y5=y1;
  378. draw z1--z3--z5;  % diagonals
  379. labels(1,3,5); endchar;
  380.  
  381. cmchar "\displaystyle lattice supremum sign";
  382. beginchar(oct"137",20u#,0,14/6dh#); padded 1/6dh#;
  383. adjust_fit(0,0); pickup pencircle scaled curve;
  384. lft x1=hround u-eps; x3=w-x3; x5=w-x1;
  385. top y1=eps; bot y3=-d; y5=y1;
  386. draw z1--z3--z5;  % diagonals
  387. labels(1,3,5); endchar;
  388.